home *** CD-ROM | disk | FTP | other *** search
/ START Magazine / START VOL 4 NO 1.st / POGOSRC.ARC / STDISK.ASM < prev    next >
Encoding:
Assembly Source File  |  1985-11-20  |  2.2 KB  |  107 lines
  1.     public _putdot
  2.     public _ahline
  3.     public _aline
  4.     public init_hli
  5.     public hli
  6.  
  7. ; useful aline offsets
  8.  
  9. ;clipping constants
  10. XMAX    equ    320    
  11. YMAX    equ    200
  12.  
  13.     public _disk
  14. _disk
  15. param1    equ    (8*4)+4+8 ;offset on stack to first parameter after register saved
  16. x        equ    param1
  17. y        equ  param1+2
  18. rad     equ    param1+4
  19. color     equ param1+6
  20. py    equ 0
  21. px1 equ 2
  22. px2 equ 4
  23. pcolor equ 6
  24. err equ 8
  25.  
  26.     movem.l    d3/d4/d5/d6/d7/a2/a3/a4,-(sp)
  27.     sub        #8,sp
  28.  
  29.     move.w    x(sp),d6    ; save center xy
  30.     move.w    y(sp),d7
  31.     move.w    color(sp),d0
  32.     and        #15,d0        ;make sure it's an ok value
  33.     move.w    rad(sp),d4    ; xoffset starts out radius
  34.     bne        nontrivd    ; it's not zero radius...do a disk
  35.  
  36.     ;    here just plot a dot cause radius zero
  37.     move.w    d6,(sp)
  38.     move.w    d7,2(sp)
  39.     move.w    d0,4(sp)
  40.     jsr        _putdot        ; else just plot one point... 
  41.     bra        enddloop
  42.  
  43. nontrivd
  44.     jsr init_hli
  45.     move.w    #0,d5        ; yoffset starts out zero
  46.     move.w    d4,d3
  47.     neg.w    d3
  48.     asr.w    #1,d3        ; d3 = error = -rad/2
  49.     move.w    d3,err(sp)
  50.  
  51.  
  52. dloop
  53.     ;    plot upper line
  54.     move.w    d6,d0    
  55.     sub.w    d4,d0    ;     find left side of hline
  56.     bpl        lclipok    ;    off screen to left?
  57.     move.w    #0,d0    ;   then make it start on left edge
  58. lclipok    
  59.     cmp.w    #XMAX,d0    ; left edge
  60.     bge        nextxy        ;off screen to right? Nothing left then.
  61.     move.w    d0,2(sp)    ; save left edge
  62.     move.w    d6,d0    
  63.     add.w    d4,d0
  64.     blt        nextxy        ; off screen to left
  65.     cmp.w    #XMAX,d0    ; calculate right edge and see if offscreen
  66.     blt        rclipok
  67.     move.w    #XMAX-1,d0    ; if offscreen make it end on right edge
  68. rclipok    
  69.     move.w    d0,4(sp) ; and save right edge
  70.     move.w    d7,d0
  71.     sub.w    d5,d0    ;   calculate absolute y coordinate
  72.     bmi        lline    ;    clipped above screen?
  73.     cmp.w    #YMAX,d0    ;clipped below screen?
  74.     bge        lline
  75.     move.w    d0,0(sp) ;     and save y position
  76.     jsr        hli
  77.  
  78. lline
  79.     move.w    d7,d0
  80.     add.w    d5,d0    ; calc y coordinate of lower line
  81.     bmi        nextxy
  82.     cmp.w    #YMAX,d0
  83.     bge        nextxy    ; if below screen don't plot it
  84.     move.w    d0,0(sp) ; save y position
  85.     jsr        hli
  86.  
  87.     ; now do stuff to figure out where next hlines will be
  88. nextxy
  89.     move.w    err(sp),d3
  90. nexty
  91.     bmi        stepy
  92.     subq.w    #1,d4
  93.     bmi        enddloop
  94.     sub.w    d4,d3
  95.     bra        nexty
  96. stepy
  97.     addq.w    #1,d5    ; increment y offset
  98.     add.w    d5,d3    ; update error term
  99.     move.w    d3,err(sp)
  100.     bra     dloop
  101.  
  102. enddloop
  103.     add        #8,sp
  104.     movem.l    (sp)+,d3/d4/d5/d6/d7/a2/a3/a4
  105.     rts
  106.  
  107.